282 lines
12 KiB
FortranFixed
282 lines
12 KiB
FortranFixed
|
SUBROUTINE ZBESK(ZR, ZI, FNU, KODE, N, CYR, CYI, NZ, IERR)
|
||
|
|
C***BEGIN PROLOGUE ZBESK
|
||
|
|
C***DATE WRITTEN 830501 (YYMMDD)
|
||
|
|
C***REVISION DATE 890801 (YYMMDD)
|
||
|
|
C***CATEGORY NO. B5K
|
||
|
|
C***KEYWORDS K-BESSEL FUNCTION,COMPLEX BESSEL FUNCTION,
|
||
|
|
C MODIFIED BESSEL FUNCTION OF THE SECOND KIND,
|
||
|
|
C BESSEL FUNCTION OF THE THIRD KIND
|
||
|
|
C***AUTHOR AMOS, DONALD E., SANDIA NATIONAL LABORATORIES
|
||
|
|
C***PURPOSE TO COMPUTE K-BESSEL FUNCTIONS OF COMPLEX ARGUMENT
|
||
|
|
C***DESCRIPTION
|
||
|
|
C
|
||
|
|
C ***A DOUBLE PRECISION ROUTINE***
|
||
|
|
C
|
||
|
|
C ON KODE=1, CBESK COMPUTES AN N MEMBER SEQUENCE OF COMPLEX
|
||
|
|
C BESSEL FUNCTIONS CY(J)=K(FNU+J-1,Z) FOR REAL, NONNEGATIVE
|
||
|
|
C ORDERS FNU+J-1, J=1,...,N AND COMPLEX Z.NE.CMPLX(0.0,0.0)
|
||
|
|
C IN THE CUT PLANE -PI.LT.ARG(Z).LE.PI. ON KODE=2, CBESK
|
||
|
|
C RETURNS THE SCALED K FUNCTIONS,
|
||
|
|
C
|
||
|
|
C CY(J)=EXP(Z)*K(FNU+J-1,Z) , J=1,...,N,
|
||
|
|
C
|
||
|
|
C WHICH REMOVE THE EXPONENTIAL BEHAVIOR IN BOTH THE LEFT AND
|
||
|
|
C RIGHT HALF PLANES FOR Z TO INFINITY. DEFINITIONS AND
|
||
|
|
C NOTATION ARE FOUND IN THE NBS HANDBOOK OF MATHEMATICAL
|
||
|
|
C FUNCTIONS (REF. 1).
|
||
|
|
C
|
||
|
|
C INPUT ZR,ZI,FNU ARE DOUBLE PRECISION
|
||
|
|
C ZR,ZI - Z=CMPLX(ZR,ZI), Z.NE.CMPLX(0.0D0,0.0D0),
|
||
|
|
C -PI.LT.ARG(Z).LE.PI
|
||
|
|
C FNU - ORDER OF INITIAL K FUNCTION, FNU.GE.0.0D0
|
||
|
|
C N - NUMBER OF MEMBERS OF THE SEQUENCE, N.GE.1
|
||
|
|
C KODE - A PARAMETER TO INDICATE THE SCALING OPTION
|
||
|
|
C KODE= 1 RETURNS
|
||
|
|
C CY(I)=K(FNU+I-1,Z), I=1,...,N
|
||
|
|
C = 2 RETURNS
|
||
|
|
C CY(I)=K(FNU+I-1,Z)*EXP(Z), I=1,...,N
|
||
|
|
C
|
||
|
|
C OUTPUT CYR,CYI ARE DOUBLE PRECISION
|
||
|
|
C CYR,CYI- DOUBLE PRECISION VECTORS WHOSE FIRST N COMPONENTS
|
||
|
|
C CONTAIN REAL AND IMAGINARY PARTS FOR THE SEQUENCE
|
||
|
|
C CY(I)=K(FNU+I-1,Z), I=1,...,N OR
|
||
|
|
C CY(I)=K(FNU+I-1,Z)*EXP(Z), I=1,...,N
|
||
|
|
C DEPENDING ON KODE
|
||
|
|
C NZ - NUMBER OF COMPONENTS SET TO ZERO DUE TO UNDERFLOW.
|
||
|
|
C NZ= 0 , NORMAL RETURN
|
||
|
|
C NZ.GT.0 , FIRST NZ COMPONENTS OF CY SET TO ZERO DUE
|
||
|
|
C TO UNDERFLOW, CY(I)=CMPLX(0.0D0,0.0D0),
|
||
|
|
C I=1,...,N WHEN X.GE.0.0. WHEN X.LT.0.0
|
||
|
|
C NZ STATES ONLY THE NUMBER OF UNDERFLOWS
|
||
|
|
C IN THE SEQUENCE.
|
||
|
|
C
|
||
|
|
C IERR - ERROR FLAG
|
||
|
|
C IERR=0, NORMAL RETURN - COMPUTATION COMPLETED
|
||
|
|
C IERR=1, INPUT ERROR - NO COMPUTATION
|
||
|
|
C IERR=2, OVERFLOW - NO COMPUTATION, FNU IS
|
||
|
|
C TOO LARGE OR CABS(Z) IS TOO SMALL OR BOTH
|
||
|
|
C IERR=3, CABS(Z) OR FNU+N-1 LARGE - COMPUTATION DONE
|
||
|
|
C BUT LOSSES OF SIGNIFCANCE BY ARGUMENT
|
||
|
|
C REDUCTION PRODUCE LESS THAN HALF OF MACHINE
|
||
|
|
C ACCURACY
|
||
|
|
C IERR=4, CABS(Z) OR FNU+N-1 TOO LARGE - NO COMPUTA-
|
||
|
|
C TION BECAUSE OF COMPLETE LOSSES OF SIGNIFI-
|
||
|
|
C CANCE BY ARGUMENT REDUCTION
|
||
|
|
C IERR=5, ERROR - NO COMPUTATION,
|
||
|
|
C ALGORITHM TERMINATION CONDITION NOT MET
|
||
|
|
C
|
||
|
|
C***LONG DESCRIPTION
|
||
|
|
C
|
||
|
|
C EQUATIONS OF THE REFERENCE ARE IMPLEMENTED FOR SMALL ORDERS
|
||
|
|
C DNU AND DNU+1.0 IN THE RIGHT HALF PLANE X.GE.0.0. FORWARD
|
||
|
|
C RECURRENCE GENERATES HIGHER ORDERS. K IS CONTINUED TO THE LEFT
|
||
|
|
C HALF PLANE BY THE RELATION
|
||
|
|
C
|
||
|
|
C K(FNU,Z*EXP(MP)) = EXP(-MP*FNU)*K(FNU,Z)-MP*I(FNU,Z)
|
||
|
|
C MP=MR*PI*I, MR=+1 OR -1, RE(Z).GT.0, I**2=-1
|
||
|
|
C
|
||
|
|
C WHERE I(FNU,Z) IS THE I BESSEL FUNCTION.
|
||
|
|
C
|
||
|
|
C FOR LARGE ORDERS, FNU.GT.FNUL, THE K FUNCTION IS COMPUTED
|
||
|
|
C BY MEANS OF ITS UNIFORM ASYMPTOTIC EXPANSIONS.
|
||
|
|
C
|
||
|
|
C FOR NEGATIVE ORDERS, THE FORMULA
|
||
|
|
C
|
||
|
|
C K(-FNU,Z) = K(FNU,Z)
|
||
|
|
C
|
||
|
|
C CAN BE USED.
|
||
|
|
C
|
||
|
|
C CBESK ASSUMES THAT A SIGNIFICANT DIGIT SINH(X) FUNCTION IS
|
||
|
|
C AVAILABLE.
|
||
|
|
C
|
||
|
|
C IN MOST COMPLEX VARIABLE COMPUTATION, ONE MUST EVALUATE ELE-
|
||
|
|
C MENTARY FUNCTIONS. WHEN THE MAGNITUDE OF Z OR FNU+N-1 IS
|
||
|
|
C LARGE, LOSSES OF SIGNIFICANCE BY ARGUMENT REDUCTION OCCUR.
|
||
|
|
C CONSEQUENTLY, IF EITHER ONE EXCEEDS U1=SQRT(0.5/UR), THEN
|
||
|
|
C LOSSES EXCEEDING HALF PRECISION ARE LIKELY AND AN ERROR FLAG
|
||
|
|
C IERR=3 IS TRIGGERED WHERE UR=DMAX1(D1MACH(4),1.0D-18) IS
|
||
|
|
C DOUBLE PRECISION UNIT ROUNDOFF LIMITED TO 18 DIGITS PRECISION.
|
||
|
|
C IF EITHER IS LARGER THAN U2=0.5/UR, THEN ALL SIGNIFICANCE IS
|
||
|
|
C LOST AND IERR=4. IN ORDER TO USE THE INT FUNCTION, ARGUMENTS
|
||
|
|
C MUST BE FURTHER RESTRICTED NOT TO EXCEED THE LARGEST MACHINE
|
||
|
|
C INTEGER, U3=I1MACH(9). THUS, THE MAGNITUDE OF Z AND FNU+N-1 IS
|
||
|
|
C RESTRICTED BY MIN(U2,U3). ON 32 BIT MACHINES, U1,U2, AND U3
|
||
|
|
C ARE APPROXIMATELY 2.0E+3, 4.2E+6, 2.1E+9 IN SINGLE PRECISION
|
||
|
|
C ARITHMETIC AND 1.3E+8, 1.8E+16, 2.1E+9 IN DOUBLE PRECISION
|
||
|
|
C ARITHMETIC RESPECTIVELY. THIS MAKES U2 AND U3 LIMITING IN
|
||
|
|
C THEIR RESPECTIVE ARITHMETICS. THIS MEANS THAT ONE CAN EXPECT
|
||
|
|
C TO RETAIN, IN THE WORST CASES ON 32 BIT MACHINES, NO DIGITS
|
||
|
|
C IN SINGLE AND ONLY 7 DIGITS IN DOUBLE PRECISION ARITHMETIC.
|
||
|
|
C SIMILAR CONSIDERATIONS HOLD FOR OTHER MACHINES.
|
||
|
|
C
|
||
|
|
C THE APPROXIMATE RELATIVE ERROR IN THE MAGNITUDE OF A COMPLEX
|
||
|
|
C BESSEL FUNCTION CAN BE EXPRESSED BY P*10**S WHERE P=MAX(UNIT
|
||
|
|
C ROUNDOFF,1.0E-18) IS THE NOMINAL PRECISION AND 10**S REPRE-
|
||
|
|
C SENTS THE INCREASE IN ERROR DUE TO ARGUMENT REDUCTION IN THE
|
||
|
|
C ELEMENTARY FUNCTIONS. HERE, S=MAX(1,ABS(LOG10(CABS(Z))),
|
||
|
|
C ABS(LOG10(FNU))) APPROXIMATELY (I.E. S=MAX(1,ABS(EXPONENT OF
|
||
|
|
C CABS(Z),ABS(EXPONENT OF FNU)) ). HOWEVER, THE PHASE ANGLE MAY
|
||
|
|
C HAVE ONLY ABSOLUTE ACCURACY. THIS IS MOST LIKELY TO OCCUR WHEN
|
||
|
|
C ONE COMPONENT (IN ABSOLUTE VALUE) IS LARGER THAN THE OTHER BY
|
||
|
|
C SEVERAL ORDERS OF MAGNITUDE. IF ONE COMPONENT IS 10**K LARGER
|
||
|
|
C THAN THE OTHER, THEN ONE CAN EXPECT ONLY MAX(ABS(LOG10(P))-K,
|
||
|
|
C 0) SIGNIFICANT DIGITS; OR, STATED ANOTHER WAY, WHEN K EXCEEDS
|
||
|
|
C THE EXPONENT OF P, NO SIGNIFICANT DIGITS REMAIN IN THE SMALLER
|
||
|
|
C COMPONENT. HOWEVER, THE PHASE ANGLE RETAINS ABSOLUTE ACCURACY
|
||
|
|
C BECAUSE, IN COMPLEX ARITHMETIC WITH PRECISION P, THE SMALLER
|
||
|
|
C COMPONENT WILL NOT (AS A RULE) DECREASE BELOW P TIMES THE
|
||
|
|
C MAGNITUDE OF THE LARGER COMPONENT. IN THESE EXTREME CASES,
|
||
|
|
C THE PRINCIPAL PHASE ANGLE IS ON THE ORDER OF +P, -P, PI/2-P,
|
||
|
|
C OR -PI/2+P.
|
||
|
|
C
|
||
|
|
C***REFERENCES HANDBOOK OF MATHEMATICAL FUNCTIONS BY M. ABRAMOWITZ
|
||
|
|
C AND I. A. STEGUN, NBS AMS SERIES 55, U.S. DEPT. OF
|
||
|
|
C COMMERCE, 1955.
|
||
|
|
C
|
||
|
|
C COMPUTATION OF BESSEL FUNCTIONS OF COMPLEX ARGUMENT
|
||
|
|
C BY D. E. AMOS, SAND83-0083, MAY, 1983.
|
||
|
|
C
|
||
|
|
C COMPUTATION OF BESSEL FUNCTIONS OF COMPLEX ARGUMENT
|
||
|
|
C AND LARGE ORDER BY D. E. AMOS, SAND83-0643, MAY, 1983.
|
||
|
|
C
|
||
|
|
C A SUBROUTINE PACKAGE FOR BESSEL FUNCTIONS OF A COMPLEX
|
||
|
|
C ARGUMENT AND NONNEGATIVE ORDER BY D. E. AMOS, SAND85-
|
||
|
|
C 1018, MAY, 1985
|
||
|
|
C
|
||
|
|
C A PORTABLE PACKAGE FOR BESSEL FUNCTIONS OF A COMPLEX
|
||
|
|
C ARGUMENT AND NONNEGATIVE ORDER BY D. E. AMOS, TRANS.
|
||
|
|
C MATH. SOFTWARE, 1986
|
||
|
|
C
|
||
|
|
C***ROUTINES CALLED ZACON,ZBKNU,ZBUNK,ZUOIK,AZABS,I1MACH,D1MACH
|
||
|
|
C***END PROLOGUE ZBESK
|
||
|
|
C
|
||
|
|
C COMPLEX CY,Z
|
||
|
|
DOUBLE PRECISION AA, ALIM, ALN, ARG, AZ, CYI, CYR, DIG, ELIM, FN,
|
||
|
|
* FNU, FNUL, RL, R1M5, TOL, UFL, ZI, ZR, D1MACH, AZABS, BB
|
||
|
|
INTEGER IERR, K, KODE, K1, K2, MR, N, NN, NUF, NW, NZ, I1MACH
|
||
|
|
DIMENSION CYR(N), CYI(N)
|
||
|
|
C***FIRST EXECUTABLE STATEMENT ZBESK
|
||
|
|
IERR = 0
|
||
|
|
NZ=0
|
||
|
|
IF (ZI.EQ.0.0E0 .AND. ZR.EQ.0.0E0) IERR=1
|
||
|
|
IF (FNU.LT.0.0D0) IERR=1
|
||
|
|
IF (KODE.LT.1 .OR. KODE.GT.2) IERR=1
|
||
|
|
IF (N.LT.1) IERR=1
|
||
|
|
IF (IERR.NE.0) RETURN
|
||
|
|
NN = N
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
C SET PARAMETERS RELATED TO MACHINE CONSTANTS.
|
||
|
|
C TOL IS THE APPROXIMATE UNIT ROUNDOFF LIMITED TO 1.0E-18.
|
||
|
|
C ELIM IS THE APPROXIMATE EXPONENTIAL OVER- AND UNDERFLOW LIMIT.
|
||
|
|
C EXP(-ELIM).LT.EXP(-ALIM)=EXP(-ELIM)/TOL AND
|
||
|
|
C EXP(ELIM).GT.EXP(ALIM)=EXP(ELIM)*TOL ARE INTERVALS NEAR
|
||
|
|
C UNDERFLOW AND OVERFLOW LIMITS WHERE SCALED ARITHMETIC IS DONE.
|
||
|
|
C RL IS THE LOWER BOUNDARY OF THE ASYMPTOTIC EXPANSION FOR LARGE Z.
|
||
|
|
C DIG = NUMBER OF BASE 10 DIGITS IN TOL = 10**(-DIG).
|
||
|
|
C FNUL IS THE LOWER BOUNDARY OF THE ASYMPTOTIC SERIES FOR LARGE FNU
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
TOL = DMAX1(D1MACH(4),1.0D-18)
|
||
|
|
K1 = I1MACH(15)
|
||
|
|
K2 = I1MACH(16)
|
||
|
|
R1M5 = D1MACH(5)
|
||
|
|
K = MIN0(IABS(K1),IABS(K2))
|
||
|
|
ELIM = 2.303D0*(DBLE(FLOAT(K))*R1M5-3.0D0)
|
||
|
|
K1 = I1MACH(14) - 1
|
||
|
|
AA = R1M5*DBLE(FLOAT(K1))
|
||
|
|
DIG = DMIN1(AA,18.0D0)
|
||
|
|
AA = AA*2.303D0
|
||
|
|
ALIM = ELIM + DMAX1(-AA,-41.45D0)
|
||
|
|
FNUL = 10.0D0 + 6.0D0*(DIG-3.0D0)
|
||
|
|
RL = 1.2D0*DIG + 3.0D0
|
||
|
|
C-----------------------------------------------------------------------------
|
||
|
|
C TEST FOR PROPER RANGE
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
AZ = AZABS(ZR,ZI)
|
||
|
|
FN = FNU + DBLE(FLOAT(NN-1))
|
||
|
|
AA = 0.5D0/TOL
|
||
|
|
BB=DBLE(FLOAT(I1MACH(9)))*0.5D0
|
||
|
|
AA = DMIN1(AA,BB)
|
||
|
|
IF (AZ.GT.AA) GO TO 260
|
||
|
|
IF (FN.GT.AA) GO TO 260
|
||
|
|
AA = DSQRT(AA)
|
||
|
|
IF (AZ.GT.AA) IERR=3
|
||
|
|
IF (FN.GT.AA) IERR=3
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
C OVERFLOW TEST ON THE LAST MEMBER OF THE SEQUENCE
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
C UFL = DEXP(-ELIM)
|
||
|
|
UFL = D1MACH(1)*1.0D+3
|
||
|
|
IF (AZ.LT.UFL) GO TO 180
|
||
|
|
IF (FNU.GT.FNUL) GO TO 80
|
||
|
|
IF (FN.LE.1.0D0) GO TO 60
|
||
|
|
IF (FN.GT.2.0D0) GO TO 50
|
||
|
|
IF (AZ.GT.TOL) GO TO 60
|
||
|
|
ARG = 0.5D0*AZ
|
||
|
|
ALN = -FN*DLOG(ARG)
|
||
|
|
IF (ALN.GT.ELIM) GO TO 180
|
||
|
|
GO TO 60
|
||
|
|
50 CONTINUE
|
||
|
|
CALL ZUOIK(ZR, ZI, FNU, KODE, 2, NN, CYR, CYI, NUF, TOL, ELIM,
|
||
|
|
* ALIM)
|
||
|
|
IF (NUF.LT.0) GO TO 180
|
||
|
|
NZ = NZ + NUF
|
||
|
|
NN = NN - NUF
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
C HERE NN=N OR NN=0 SINCE NUF=0,NN, OR -1 ON RETURN FROM CUOIK
|
||
|
|
C IF NUF=NN, THEN CY(I)=CZERO FOR ALL I
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
IF (NN.EQ.0) GO TO 100
|
||
|
|
60 CONTINUE
|
||
|
|
IF (ZR.LT.0.0D0) GO TO 70
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
C RIGHT HALF PLANE COMPUTATION, REAL(Z).GE.0.
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
CALL ZBKNU(ZR, ZI, FNU, KODE, NN, CYR, CYI, NW, TOL, ELIM, ALIM)
|
||
|
|
IF (NW.LT.0) GO TO 200
|
||
|
|
NZ=NW
|
||
|
|
RETURN
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
C LEFT HALF PLANE COMPUTATION
|
||
|
|
C PI/2.LT.ARG(Z).LE.PI AND -PI.LT.ARG(Z).LT.-PI/2.
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
70 CONTINUE
|
||
|
|
IF (NZ.NE.0) GO TO 180
|
||
|
|
MR = 1
|
||
|
|
IF (ZI.LT.0.0D0) MR = -1
|
||
|
|
CALL ZACON(ZR, ZI, FNU, KODE, MR, NN, CYR, CYI, NW, RL, FNUL,
|
||
|
|
* TOL, ELIM, ALIM)
|
||
|
|
IF (NW.LT.0) GO TO 200
|
||
|
|
NZ=NW
|
||
|
|
RETURN
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
C UNIFORM ASYMPTOTIC EXPANSIONS FOR FNU.GT.FNUL
|
||
|
|
C-----------------------------------------------------------------------
|
||
|
|
80 CONTINUE
|
||
|
|
MR = 0
|
||
|
|
IF (ZR.GE.0.0D0) GO TO 90
|
||
|
|
MR = 1
|
||
|
|
IF (ZI.LT.0.0D0) MR = -1
|
||
|
|
90 CONTINUE
|
||
|
|
CALL ZBUNK(ZR, ZI, FNU, KODE, MR, NN, CYR, CYI, NW, TOL, ELIM,
|
||
|
|
* ALIM)
|
||
|
|
IF (NW.LT.0) GO TO 200
|
||
|
|
NZ = NZ + NW
|
||
|
|
RETURN
|
||
|
|
100 CONTINUE
|
||
|
|
IF (ZR.LT.0.0D0) GO TO 180
|
||
|
|
RETURN
|
||
|
|
180 CONTINUE
|
||
|
|
NZ = 0
|
||
|
|
IERR=2
|
||
|
|
RETURN
|
||
|
|
200 CONTINUE
|
||
|
|
IF(NW.EQ.(-1)) GO TO 180
|
||
|
|
NZ=0
|
||
|
|
IERR=5
|
||
|
|
RETURN
|
||
|
|
260 CONTINUE
|
||
|
|
NZ=0
|
||
|
|
IERR=4
|
||
|
|
RETURN
|
||
|
|
END
|