349 lines
14 KiB
Fortran
349 lines
14 KiB
Fortran
SUBROUTINE ZBESH(ZR, ZI, FNU, KODE, M, N, CYR, CYI, NZ, IERR)
|
|
C***BEGIN PROLOGUE ZBESH
|
|
C***DATE WRITTEN 830501 (YYMMDD)
|
|
C***REVISION DATE 890801 (YYMMDD)
|
|
C***CATEGORY NO. B5K
|
|
C***KEYWORDS H-BESSEL FUNCTIONS,BESSEL FUNCTIONS OF COMPLEX ARGUMENT,
|
|
C BESSEL FUNCTIONS OF THIRD KIND,HANKEL FUNCTIONS
|
|
C***AUTHOR AMOS, DONALD E., SANDIA NATIONAL LABORATORIES
|
|
C***PURPOSE TO COMPUTE THE H-BESSEL FUNCTIONS OF A COMPLEX ARGUMENT
|
|
C***DESCRIPTION
|
|
C
|
|
C ***A DOUBLE PRECISION ROUTINE***
|
|
C ON KODE=1, ZBESH COMPUTES AN N MEMBER SEQUENCE OF COMPLEX
|
|
C HANKEL (BESSEL) FUNCTIONS CY(J)=H(M,FNU+J-1,Z) FOR KINDS M=1
|
|
C OR 2, REAL, NONNEGATIVE ORDERS FNU+J-1, J=1,...,N, AND COMPLEX
|
|
C Z.NE.CMPLX(0.0,0.0) IN THE CUT PLANE -PI.LT.ARG(Z).LE.PI.
|
|
C ON KODE=2, ZBESH RETURNS THE SCALED HANKEL FUNCTIONS
|
|
C
|
|
C CY(I)=EXP(-MM*Z*I)*H(M,FNU+J-1,Z) MM=3-2*M, I**2=-1.
|
|
C
|
|
C WHICH REMOVES THE EXPONENTIAL BEHAVIOR IN BOTH THE UPPER AND
|
|
C LOWER HALF PLANES. DEFINITIONS AND NOTATION ARE FOUND IN THE
|
|
C NBS HANDBOOK OF MATHEMATICAL FUNCTIONS (REF. 1).
|
|
C
|
|
C INPUT ZR,ZI,FNU ARE DOUBLE PRECISION
|
|
C ZR,ZI - Z=CMPLX(ZR,ZI), Z.NE.CMPLX(0.0D0,0.0D0),
|
|
C -PT.LT.ARG(Z).LE.PI
|
|
C FNU - ORDER OF INITIAL H FUNCTION, FNU.GE.0.0D0
|
|
C KODE - A PARAMETER TO INDICATE THE SCALING OPTION
|
|
C KODE= 1 RETURNS
|
|
C CY(J)=H(M,FNU+J-1,Z), J=1,...,N
|
|
C = 2 RETURNS
|
|
C CY(J)=H(M,FNU+J-1,Z)*EXP(-I*Z*(3-2M))
|
|
C J=1,...,N , I**2=-1
|
|
C M - KIND OF HANKEL FUNCTION, M=1 OR 2
|
|
C N - NUMBER OF MEMBERS IN THE SEQUENCE, N.GE.1
|
|
C
|
|
C OUTPUT CYR,CYI ARE DOUBLE PRECISION
|
|
C CYR,CYI- DOUBLE PRECISION VECTORS WHOSE FIRST N COMPONENTS
|
|
C CONTAIN REAL AND IMAGINARY PARTS FOR THE SEQUENCE
|
|
C CY(J)=H(M,FNU+J-1,Z) OR
|
|
C CY(J)=H(M,FNU+J-1,Z)*EXP(-I*Z*(3-2M)) J=1,...,N
|
|
C DEPENDING ON KODE, I**2=-1.
|
|
C NZ - NUMBER OF COMPONENTS SET TO ZERO DUE TO UNDERFLOW,
|
|
C NZ= 0 , NORMAL RETURN
|
|
C NZ.GT.0 , FIRST NZ COMPONENTS OF CY SET TO ZERO DUE
|
|
C TO UNDERFLOW, CY(J)=CMPLX(0.0D0,0.0D0)
|
|
C J=1,...,NZ WHEN Y.GT.0.0 AND M=1 OR
|
|
C Y.LT.0.0 AND M=2. FOR THE COMPLMENTARY
|
|
C HALF PLANES, NZ STATES ONLY THE NUMBER
|
|
C OF UNDERFLOWS.
|
|
C IERR - ERROR FLAG
|
|
C IERR=0, NORMAL RETURN - COMPUTATION COMPLETED
|
|
C IERR=1, INPUT ERROR - NO COMPUTATION
|
|
C IERR=2, OVERFLOW - NO COMPUTATION, FNU TOO
|
|
C LARGE OR CABS(Z) TOO SMALL OR BOTH
|
|
C IERR=3, CABS(Z) OR FNU+N-1 LARGE - COMPUTATION DONE
|
|
C BUT LOSSES OF SIGNIFCANCE BY ARGUMENT
|
|
C REDUCTION PRODUCE LESS THAN HALF OF MACHINE
|
|
C ACCURACY
|
|
C IERR=4, CABS(Z) OR FNU+N-1 TOO LARGE - NO COMPUTA-
|
|
C TION BECAUSE OF COMPLETE LOSSES OF SIGNIFI-
|
|
C CANCE BY ARGUMENT REDUCTION
|
|
C IERR=5, ERROR - NO COMPUTATION,
|
|
C ALGORITHM TERMINATION CONDITION NOT MET
|
|
C
|
|
C***LONG DESCRIPTION
|
|
C
|
|
C THE COMPUTATION IS CARRIED OUT BY THE RELATION
|
|
C
|
|
C H(M,FNU,Z)=(1/MP)*EXP(-MP*FNU)*K(FNU,Z*EXP(-MP))
|
|
C MP=MM*HPI*I, MM=3-2*M, HPI=PI/2, I**2=-1
|
|
C
|
|
C FOR M=1 OR 2 WHERE THE K BESSEL FUNCTION IS COMPUTED FOR THE
|
|
C RIGHT HALF PLANE RE(Z).GE.0.0. THE K FUNCTION IS CONTINUED
|
|
C TO THE LEFT HALF PLANE BY THE RELATION
|
|
C
|
|
C K(FNU,Z*EXP(MP)) = EXP(-MP*FNU)*K(FNU,Z)-MP*I(FNU,Z)
|
|
C MP=MR*PI*I, MR=+1 OR -1, RE(Z).GT.0, I**2=-1
|
|
C
|
|
C WHERE I(FNU,Z) IS THE I BESSEL FUNCTION.
|
|
C
|
|
C EXPONENTIAL DECAY OF H(M,FNU,Z) OCCURS IN THE UPPER HALF Z
|
|
C PLANE FOR M=1 AND THE LOWER HALF Z PLANE FOR M=2. EXPONENTIAL
|
|
C GROWTH OCCURS IN THE COMPLEMENTARY HALF PLANES. SCALING
|
|
C BY EXP(-MM*Z*I) REMOVES THE EXPONENTIAL BEHAVIOR IN THE
|
|
C WHOLE Z PLANE FOR Z TO INFINITY.
|
|
C
|
|
C FOR NEGATIVE ORDERS,THE FORMULAE
|
|
C
|
|
C H(1,-FNU,Z) = H(1,FNU,Z)*CEXP( PI*FNU*I)
|
|
C H(2,-FNU,Z) = H(2,FNU,Z)*CEXP(-PI*FNU*I)
|
|
C I**2=-1
|
|
C
|
|
C CAN BE USED.
|
|
C
|
|
C IN MOST COMPLEX VARIABLE COMPUTATION, ONE MUST EVALUATE ELE-
|
|
C MENTARY FUNCTIONS. WHEN THE MAGNITUDE OF Z OR FNU+N-1 IS
|
|
C LARGE, LOSSES OF SIGNIFICANCE BY ARGUMENT REDUCTION OCCUR.
|
|
C CONSEQUENTLY, IF EITHER ONE EXCEEDS U1=SQRT(0.5/UR), THEN
|
|
C LOSSES EXCEEDING HALF PRECISION ARE LIKELY AND AN ERROR FLAG
|
|
C IERR=3 IS TRIGGERED WHERE UR=DMAX1(D1MACH(4),1.0D-18) IS
|
|
C DOUBLE PRECISION UNIT ROUNDOFF LIMITED TO 18 DIGITS PRECISION.
|
|
C IF EITHER IS LARGER THAN U2=0.5/UR, THEN ALL SIGNIFICANCE IS
|
|
C LOST AND IERR=4. IN ORDER TO USE THE INT FUNCTION, ARGUMENTS
|
|
C MUST BE FURTHER RESTRICTED NOT TO EXCEED THE LARGEST MACHINE
|
|
C INTEGER, U3=I1MACH(9). THUS, THE MAGNITUDE OF Z AND FNU+N-1 IS
|
|
C RESTRICTED BY MIN(U2,U3). ON 32 BIT MACHINES, U1,U2, AND U3
|
|
C ARE APPROXIMATELY 2.0E+3, 4.2E+6, 2.1E+9 IN SINGLE PRECISION
|
|
C ARITHMETIC AND 1.3E+8, 1.8E+16, 2.1E+9 IN DOUBLE PRECISION
|
|
C ARITHMETIC RESPECTIVELY. THIS MAKES U2 AND U3 LIMITING IN
|
|
C THEIR RESPECTIVE ARITHMETICS. THIS MEANS THAT ONE CAN EXPECT
|
|
C TO RETAIN, IN THE WORST CASES ON 32 BIT MACHINES, NO DIGITS
|
|
C IN SINGLE AND ONLY 7 DIGITS IN DOUBLE PRECISION ARITHMETIC.
|
|
C SIMILAR CONSIDERATIONS HOLD FOR OTHER MACHINES.
|
|
C
|
|
C THE APPROXIMATE RELATIVE ERROR IN THE MAGNITUDE OF A COMPLEX
|
|
C BESSEL FUNCTION CAN BE EXPRESSED BY P*10**S WHERE P=MAX(UNIT
|
|
C ROUNDOFF,1.0D-18) IS THE NOMINAL PRECISION AND 10**S REPRE-
|
|
C SENTS THE INCREASE IN ERROR DUE TO ARGUMENT REDUCTION IN THE
|
|
C ELEMENTARY FUNCTIONS. HERE, S=MAX(1,ABS(LOG10(CABS(Z))),
|
|
C ABS(LOG10(FNU))) APPROXIMATELY (I.E. S=MAX(1,ABS(EXPONENT OF
|
|
C CABS(Z),ABS(EXPONENT OF FNU)) ). HOWEVER, THE PHASE ANGLE MAY
|
|
C HAVE ONLY ABSOLUTE ACCURACY. THIS IS MOST LIKELY TO OCCUR WHEN
|
|
C ONE COMPONENT (IN ABSOLUTE VALUE) IS LARGER THAN THE OTHER BY
|
|
C SEVERAL ORDERS OF MAGNITUDE. IF ONE COMPONENT IS 10**K LARGER
|
|
C THAN THE OTHER, THEN ONE CAN EXPECT ONLY MAX(ABS(LOG10(P))-K,
|
|
C 0) SIGNIFICANT DIGITS; OR, STATED ANOTHER WAY, WHEN K EXCEEDS
|
|
C THE EXPONENT OF P, NO SIGNIFICANT DIGITS REMAIN IN THE SMALLER
|
|
C COMPONENT. HOWEVER, THE PHASE ANGLE RETAINS ABSOLUTE ACCURACY
|
|
C BECAUSE, IN COMPLEX ARITHMETIC WITH PRECISION P, THE SMALLER
|
|
C COMPONENT WILL NOT (AS A RULE) DECREASE BELOW P TIMES THE
|
|
C MAGNITUDE OF THE LARGER COMPONENT. IN THESE EXTREME CASES,
|
|
C THE PRINCIPAL PHASE ANGLE IS ON THE ORDER OF +P, -P, PI/2-P,
|
|
C OR -PI/2+P.
|
|
C
|
|
C***REFERENCES HANDBOOK OF MATHEMATICAL FUNCTIONS BY M. ABRAMOWITZ
|
|
C AND I. A. STEGUN, NBS AMS SERIES 55, U.S. DEPT. OF
|
|
C COMMERCE, 1955.
|
|
C
|
|
C COMPUTATION OF BESSEL FUNCTIONS OF COMPLEX ARGUMENT
|
|
C BY D. E. AMOS, SAND83-0083, MAY, 1983.
|
|
C
|
|
C COMPUTATION OF BESSEL FUNCTIONS OF COMPLEX ARGUMENT
|
|
C AND LARGE ORDER BY D. E. AMOS, SAND83-0643, MAY, 1983
|
|
C
|
|
C A SUBROUTINE PACKAGE FOR BESSEL FUNCTIONS OF A COMPLEX
|
|
C ARGUMENT AND NONNEGATIVE ORDER BY D. E. AMOS, SAND85-
|
|
C 1018, MAY, 1985
|
|
C
|
|
C A PORTABLE PACKAGE FOR BESSEL FUNCTIONS OF A COMPLEX
|
|
C ARGUMENT AND NONNEGATIVE ORDER BY D. E. AMOS, TRANS.
|
|
C MATH. SOFTWARE, 1986
|
|
C
|
|
C***ROUTINES CALLED ZACON,ZBKNU,ZBUNK,ZUOIK,AZABS,I1MACH,D1MACH
|
|
C***END PROLOGUE ZBESH
|
|
C
|
|
C COMPLEX CY,Z,ZN,ZT,CSGN
|
|
DOUBLE PRECISION AA, ALIM, ALN, ARG, AZ, CYI, CYR, DIG, ELIM,
|
|
* FMM, FN, FNU, FNUL, HPI, RHPI, RL, R1M5, SGN, STR, TOL, UFL, ZI,
|
|
* ZNI, ZNR, ZR, ZTI, D1MACH, AZABS, BB, ASCLE, RTOL, ATOL, STI,
|
|
* CSGNR, CSGNI
|
|
INTEGER I, IERR, INU, INUH, IR, K, KODE, K1, K2, M,
|
|
* MM, MR, N, NN, NUF, NW, NZ, I1MACH
|
|
DIMENSION CYR(N), CYI(N)
|
|
C
|
|
DATA HPI /1.57079632679489662D0/
|
|
C
|
|
C***FIRST EXECUTABLE STATEMENT ZBESH
|
|
IERR = 0
|
|
NZ=0
|
|
IF (ZR.EQ.0.0D0 .AND. ZI.EQ.0.0D0) IERR=1
|
|
IF (FNU.LT.0.0D0) IERR=1
|
|
IF (M.LT.1 .OR. M.GT.2) IERR=1
|
|
IF (KODE.LT.1 .OR. KODE.GT.2) IERR=1
|
|
IF (N.LT.1) IERR=1
|
|
IF (IERR.NE.0) RETURN
|
|
NN = N
|
|
C-----------------------------------------------------------------------
|
|
C SET PARAMETERS RELATED TO MACHINE CONSTANTS.
|
|
C TOL IS THE APPROXIMATE UNIT ROUNDOFF LIMITED TO 1.0E-18.
|
|
C ELIM IS THE APPROXIMATE EXPONENTIAL OVER- AND UNDERFLOW LIMIT.
|
|
C EXP(-ELIM).LT.EXP(-ALIM)=EXP(-ELIM)/TOL AND
|
|
C EXP(ELIM).GT.EXP(ALIM)=EXP(ELIM)*TOL ARE INTERVALS NEAR
|
|
C UNDERFLOW AND OVERFLOW LIMITS WHERE SCALED ARITHMETIC IS DONE.
|
|
C RL IS THE LOWER BOUNDARY OF THE ASYMPTOTIC EXPANSION FOR LARGE Z.
|
|
C DIG = NUMBER OF BASE 10 DIGITS IN TOL = 10**(-DIG).
|
|
C FNUL IS THE LOWER BOUNDARY OF THE ASYMPTOTIC SERIES FOR LARGE FNU
|
|
C-----------------------------------------------------------------------
|
|
TOL = DMAX1(D1MACH(4),1.0D-18)
|
|
K1 = I1MACH(15)
|
|
K2 = I1MACH(16)
|
|
R1M5 = D1MACH(5)
|
|
K = MIN0(IABS(K1),IABS(K2))
|
|
ELIM = 2.303D0*(DBLE(FLOAT(K))*R1M5-3.0D0)
|
|
K1 = I1MACH(14) - 1
|
|
AA = R1M5*DBLE(FLOAT(K1))
|
|
DIG = DMIN1(AA,18.0D0)
|
|
AA = AA*2.303D0
|
|
ALIM = ELIM + DMAX1(-AA,-41.45D0)
|
|
FNUL = 10.0D0 + 6.0D0*(DIG-3.0D0)
|
|
RL = 1.2D0*DIG + 3.0D0
|
|
FN = FNU + DBLE(FLOAT(NN-1))
|
|
MM = 3 - M - M
|
|
FMM = DBLE(FLOAT(MM))
|
|
ZNR = FMM*ZI
|
|
ZNI = -FMM*ZR
|
|
C-----------------------------------------------------------------------
|
|
C TEST FOR PROPER RANGE
|
|
C-----------------------------------------------------------------------
|
|
AZ = AZABS(ZR,ZI)
|
|
AA = 0.5D0/TOL
|
|
BB=DBLE(FLOAT(I1MACH(9)))*0.5D0
|
|
AA = DMIN1(AA,BB)
|
|
IF (AZ.GT.AA) GO TO 260
|
|
IF (FN.GT.AA) GO TO 260
|
|
AA = DSQRT(AA)
|
|
IF (AZ.GT.AA) IERR=3
|
|
IF (FN.GT.AA) IERR=3
|
|
C-----------------------------------------------------------------------
|
|
C OVERFLOW TEST ON THE LAST MEMBER OF THE SEQUENCE
|
|
C-----------------------------------------------------------------------
|
|
UFL = D1MACH(1)*1.0D+3
|
|
IF (AZ.LT.UFL) GO TO 230
|
|
IF (FNU.GT.FNUL) GO TO 90
|
|
IF (FN.LE.1.0D0) GO TO 70
|
|
IF (FN.GT.2.0D0) GO TO 60
|
|
IF (AZ.GT.TOL) GO TO 70
|
|
ARG = 0.5D0*AZ
|
|
ALN = -FN*DLOG(ARG)
|
|
IF (ALN.GT.ELIM) GO TO 230
|
|
GO TO 70
|
|
60 CONTINUE
|
|
CALL ZUOIK(ZNR, ZNI, FNU, KODE, 2, NN, CYR, CYI, NUF, TOL, ELIM,
|
|
* ALIM)
|
|
IF (NUF.LT.0) GO TO 230
|
|
NZ = NZ + NUF
|
|
NN = NN - NUF
|
|
C-----------------------------------------------------------------------
|
|
C HERE NN=N OR NN=0 SINCE NUF=0,NN, OR -1 ON RETURN FROM CUOIK
|
|
C IF NUF=NN, THEN CY(I)=CZERO FOR ALL I
|
|
C-----------------------------------------------------------------------
|
|
IF (NN.EQ.0) GO TO 140
|
|
70 CONTINUE
|
|
IF ((ZNR.LT.0.0D0) .OR. (ZNR.EQ.0.0D0 .AND. ZNI.LT.0.0D0 .AND.
|
|
* M.EQ.2)) GO TO 80
|
|
C-----------------------------------------------------------------------
|
|
C RIGHT HALF PLANE COMPUTATION, XN.GE.0. .AND. (XN.NE.0. .OR.
|
|
C YN.GE.0. .OR. M=1)
|
|
C-----------------------------------------------------------------------
|
|
CALL ZBKNU(ZNR, ZNI, FNU, KODE, NN, CYR, CYI, NZ, TOL, ELIM, ALIM)
|
|
GO TO 110
|
|
C-----------------------------------------------------------------------
|
|
C LEFT HALF PLANE COMPUTATION
|
|
C-----------------------------------------------------------------------
|
|
80 CONTINUE
|
|
MR = -MM
|
|
CALL ZACON(ZNR, ZNI, FNU, KODE, MR, NN, CYR, CYI, NW, RL, FNUL,
|
|
* TOL, ELIM, ALIM)
|
|
IF (NW.LT.0) GO TO 240
|
|
NZ=NW
|
|
GO TO 110
|
|
90 CONTINUE
|
|
C-----------------------------------------------------------------------
|
|
C UNIFORM ASYMPTOTIC EXPANSIONS FOR FNU.GT.FNUL
|
|
C-----------------------------------------------------------------------
|
|
MR = 0
|
|
IF ((ZNR.GE.0.0D0) .AND. (ZNR.NE.0.0D0 .OR. ZNI.GE.0.0D0 .OR.
|
|
* M.NE.2)) GO TO 100
|
|
MR = -MM
|
|
IF (ZNR.NE.0.0D0 .OR. ZNI.GE.0.0D0) GO TO 100
|
|
ZNR = -ZNR
|
|
ZNI = -ZNI
|
|
100 CONTINUE
|
|
CALL ZBUNK(ZNR, ZNI, FNU, KODE, MR, NN, CYR, CYI, NW, TOL, ELIM,
|
|
* ALIM)
|
|
IF (NW.LT.0) GO TO 240
|
|
NZ = NZ + NW
|
|
110 CONTINUE
|
|
C-----------------------------------------------------------------------
|
|
C H(M,FNU,Z) = -FMM*(I/HPI)*(ZT**FNU)*K(FNU,-Z*ZT)
|
|
C
|
|
C ZT=EXP(-FMM*HPI*I) = CMPLX(0.0,-FMM), FMM=3-2*M, M=1,2
|
|
C-----------------------------------------------------------------------
|
|
SGN = DSIGN(HPI,-FMM)
|
|
C-----------------------------------------------------------------------
|
|
C CALCULATE EXP(FNU*HPI*I) TO MINIMIZE LOSSES OF SIGNIFICANCE
|
|
C WHEN FNU IS LARGE
|
|
C-----------------------------------------------------------------------
|
|
INU = INT(SNGL(FNU))
|
|
INUH = INU/2
|
|
IR = INU - 2*INUH
|
|
ARG = (FNU-DBLE(FLOAT(INU-IR)))*SGN
|
|
RHPI = 1.0D0/SGN
|
|
C ZNI = RHPI*DCOS(ARG)
|
|
C ZNR = -RHPI*DSIN(ARG)
|
|
CSGNI = RHPI*DCOS(ARG)
|
|
CSGNR = -RHPI*DSIN(ARG)
|
|
IF (MOD(INUH,2).EQ.0) GO TO 120
|
|
C ZNR = -ZNR
|
|
C ZNI = -ZNI
|
|
CSGNR = -CSGNR
|
|
CSGNI = -CSGNI
|
|
120 CONTINUE
|
|
ZTI = -FMM
|
|
RTOL = 1.0D0/TOL
|
|
ASCLE = UFL*RTOL
|
|
DO 130 I=1,NN
|
|
C STR = CYR(I)*ZNR - CYI(I)*ZNI
|
|
C CYI(I) = CYR(I)*ZNI + CYI(I)*ZNR
|
|
C CYR(I) = STR
|
|
C STR = -ZNI*ZTI
|
|
C ZNI = ZNR*ZTI
|
|
C ZNR = STR
|
|
AA = CYR(I)
|
|
BB = CYI(I)
|
|
ATOL = 1.0D0
|
|
IF (DMAX1(DABS(AA),DABS(BB)).GT.ASCLE) GO TO 135
|
|
AA = AA*RTOL
|
|
BB = BB*RTOL
|
|
ATOL = TOL
|
|
135 CONTINUE
|
|
STR = AA*CSGNR - BB*CSGNI
|
|
STI = AA*CSGNI + BB*CSGNR
|
|
CYR(I) = STR*ATOL
|
|
CYI(I) = STI*ATOL
|
|
STR = -CSGNI*ZTI
|
|
CSGNI = CSGNR*ZTI
|
|
CSGNR = STR
|
|
130 CONTINUE
|
|
RETURN
|
|
140 CONTINUE
|
|
IF (ZNR.LT.0.0D0) GO TO 230
|
|
RETURN
|
|
230 CONTINUE
|
|
NZ=0
|
|
IERR=2
|
|
RETURN
|
|
240 CONTINUE
|
|
IF(NW.EQ.(-1)) GO TO 230
|
|
NZ=0
|
|
IERR=5
|
|
RETURN
|
|
260 CONTINUE
|
|
NZ=0
|
|
IERR=4
|
|
RETURN
|
|
END
|